AWS만 쓰던 사람이 Azure 써 보는 이야기: (2) 서버

resource "azurerm_linux_virtual_machine" "gonigoni_vm" {
  # 중간 생략
  source_image_reference {
    publisher = "Canonical"
    offer     = "ubuntu-24_04-lts"
    sku       = "server"
    version   = "latest"
  }
}

az vm image list --publisher resf --offer rockylinux-x86_64 --all --output table

# Output
Architecture    Offer              Publisher    Sku     Urn                                         Version
--------------  -----------------  -----------  ------  ------------------------------------------  ------------
# ...
x64             rockylinux-x86_64  resf         9-base  resf:rockylinux-x86_64:9-base:9.6.20250531  9.6.20250531
# ...

az vm image terms show --urn resf:rockylinux-x86_64:9-base:latest

# Output
{
  "accepted": false,
  # 중간 생략
  "name": "9-base",
  "plan": "9-base",
  "product": "rockylinux-x86_64",
  "publisher": "resf",
  # 중간 생략
}

az vm image terms accept --urn resf:rockylinux-x86_64:9-base:latest

# Output
{
  "accepted": true,
  # 중간 생략
  "name": "9-base",
  "plan": "9-base",
  "publisher": "resf",
  "product": "rockylinux-x86_64",
  # 중간 생략
}

resource "azurerm_linux_virtual_machine" "gonigoni_vm" {
  # 나머지는 생략 

  # 소스 이미지 지정
  source_image_reference {
    publisher = "resf"
    offer     = "rockylinux-x86_64"
    sku       = "9-base"
    version   = "latest"
  }

  # Plan 지정: `az vm image terms show` 명령의 결과를 참조하여 작성합니다.
  plan {
    publisher = "resf"
    product   = "rockylinux-x86_64"
    name      = "9-base"
  }
}

$ ssh -i your_private_key.pem youradminuser@your_vm_public_ip
[youradminuser@gonigoni_vm ~]$ cat /etc/os-release
NAME="Rocky Linux"
VERSION="9.6 (Blue Onyx)"

# 가상 머신에서 사용할 공인 IP
resource "azurerm_public_ip" "gonigoni_vm_public_ip" {
  name                = "gonigoni-vm-public-ip"
  # 리소스 그룹, 위치 설정은 생략
  allocation_method = "Static"
}

# 네트워크 인터페이스
resource "azurerm_network_interface" "gonigoni_vm_nic" {
  name                = "gonigoni-vm-nic"
  # 리소스 그룹, 위치 설정은 생략

  ip_configuration {
    name                          = "internal"
    subnet_id                     = azurerm_subnet.gonigoni_public_subnet.id
    private_ip_address_allocation = "Dynamic"
    public_ip_address_id          = azurerm_public_ip.gonigoni_vm_public_ip.id
  }
}

# 네트워크 보안 그룹 (외부에서 SSH 접근 허용)
resource "azurerm_network_security_group" "gonigoni_vm_nsg" {
  name                = "gonigoni-vm-nsg"
  # 리소스 그룹, 위치 설정은 생략

  security_rule {
    name                       = "SSH"
    priority                   = 1001
    direction                  = "Inbound"
    access                     = "Allow"
    protocol                   = "Tcp"
    source_port_range          = "*"
    destination_port_range     = "22"
    source_address_prefix      = "*"
    destination_address_prefix = "*"
  }
}

# 네트워크 인터페이스와 네트워크 보안 그룹 연결
resource "azurerm_network_interface_security_group_association" "gonigoni_vm_nic_nsg_assoc" {
  network_interface_id      = azurerm_network_interface.gonigoni_vm_nic.id
  network_security_group_id = azurerm_network_security_group.gonigoni_vm_nsg.id
}

# 가상 머신
resource "azurerm_linux_virtual_machine" "gonigoni_vm" {
  name                  = "gonigoni-vm"
  # 리소스 그룹, 위치 설정은 생략
  size                  = "Standard_B2as_V2"
  admin_username        = "youradminuser"
  network_interface_ids = [azurerm_network_interface.gonigoni_vm_nic.id]

  # 중간 생략
}

data "azurerm_ssh_public_key" "test" {
  name                = "your_test_public_key"
  resource_group_name = "your_resource_group"
}

resource "azurerm_linux_virtual_machine" "gonigoni_vm" {
  # 중간 생략

  admin_ssh_key {
    username   = "youradminuser"
    # 아래와 같이 공개 키를 지정해 줍니다.
    public_key = data.azurerm_ssh_public_key.test.public_key
  }

  # 중간 생략
}

resource "azapi_resource_action" "ssh_public_key_gen" {
  type        = "Microsoft.Compute/sshPublicKeys@2022-11-01"
  resource_id = azapi_resource.ssh_public_key.id
  action      = "generateKeyPair"
  method      = "POST"

  # 아래 설정에 주목하세요!
  response_export_values = ["publicKey", "privateKey"]
}

resource "azapi_resource" "ssh_public_key" {
  type      = "Microsoft.Compute/sshPublicKeys@2022-11-01"
  name      = "my_ssh_key"
  # 리소스 그룹과 위치 정보는 생략
}

resource "azurerm_linux_virtual_machine" "gonigoni_vm" {
  # 중간 생략

  admin_ssh_key {
    username   = "gonigoni"
    # 생성한 공개 키를 참조합니다.
    public_key = azapi_resource_action.ssh_public_key_gen.output.publicKey
  }

  # 중간 생략
}

# 개인 키를 output으로 등록합니다.
output "ssh_private_key" {
  value = azapi_resource_action.ssh_public_key_gen.output.privateKey
  # plan이나 apply 시 개인 키를 노출하지 않기 위해 설정합니다.
  sensitive = true
}

terraform output -raw ssh_private_key > my_private_key.pem
chmod 400 my_private_key.pem

terraform console
# `>` 뒤의 내용을 입력합니다.
> azapi_resource_action.ssh_public_key_gen.output.privateKey
# EOT 사이에 출력된 내용을 복사해서 별도의 파일로 저장합니다. `chmod`로 400으로 권한을 변경해야 정상 실행 가능합니다.

resource "azurerm_orchestrated_virtual_machine_scale_set" "gonigoni_test" {
  name                        = "gonigoni-vmss"
  resource_group_name         = azurerm_resource_group.gonigoni.name
  location                    = azurerm_resource_group.gonigoni.location
  platform_fault_domain_count = 1
  instances                   = 2                  # 서버 대수

  sku_name = "Mix"
  sku_profile {
    # 서버 타입: 최대 5개까지 설정 가능
    vm_sizes = ["Standard_D2as_v6"]

    # allocation_strategy에 대한 설명: https://learn.microsoft.com/ko-kr/azure/virtual-machine-scale-sets/instance-mix-overview
    # LowestPrice가 기본값이며, 안정성이 중요하면 CapacityOptimized를 사용
    allocation_strategy = "CapacityOptimized"
  }

  os_profile {
    linux_configuration {
      admin_username = "azureuser"

      # SSH Key
      admin_ssh_key {
        username   = "azureuser"
        public_key = data.azurerm_ssh_public_key.gonigoni_v2.public_key
      }
    }
  }

  # Ubuntu 24.04 LTS
  source_image_reference {
    publisher = "Canonical"
    offer     = "ubuntu-24_04-lts"
    sku       = "server"
    version   = "latest"
  }

  # OS Disk
  os_disk {
    storage_account_type = "Standard_LRS"
    caching              = "ReadWrite"
  }

  # 네트워크 인터페이스
  network_interface {
    name    = "gonigoni-vmss-nic"
    primary = true

    ip_configuration {
      name      = "internal"
      primary   = true
      subnet_id = azurerm_subnet.gonigoni_private_subnet.id
    }

    # 네트워크 보안 그룹과 연결
    network_security_group_id = azurerm_network_security_group.gonigoni_vmss_nsg.id
  }
}